33 lines
960 B
Python
33 lines
960 B
Python
# vim:syntax=python
|
|
|
|
install_dir = '/usr/lib/gnome-screensaver/gnome-screensaver'
|
|
load_files = ['logo/dwlogo.obj', 'logo/dwlogo.mtl']
|
|
|
|
env = Environment(CPPPATH = ['.'])
|
|
env.ParseConfig("pkg-config --cflags --libs glib-2.0 gdk-2.0 atk gtk+-2.0 gtkglext-1.0")
|
|
|
|
genLoadFile = Builder(action = 'perl genLoadFile.pl --root=logo $SOURCES')
|
|
env.Append(BUILDERS = {'LoadFile' : genLoadFile})
|
|
|
|
def gen_modes(target, source, env):
|
|
f = open(str(target[0]), 'w')
|
|
for s in source:
|
|
f.write("#include \"%s\"\n" % str(s))
|
|
f.close()
|
|
return None;
|
|
|
|
genModes = Builder(action = gen_modes)
|
|
env.Append(BUILDERS = {'Modes' : genModes})
|
|
|
|
sources = [Glob('*.c'), Glob('*.cc'), Glob('LoadFile/*.cc'), Glob('modes/*.cc')]
|
|
|
|
env.LoadFile('LoadFile-gen.inc', load_files)
|
|
env.Depends('LoadFile-gen.inc', 'genLoadFile.pl')
|
|
|
|
env.Modes('modes.h', Glob('modes/*.h'))
|
|
|
|
dwss = env.Program('dwss', sources)
|
|
|
|
env.Install(install_dir, dwss)
|
|
env.Alias('install', install_dir)
|