/**
 * HULK Console functionality.
 */
module hulk.console;

import hulk.fb;
import hulk.kfont;

struct console
{
    private static __gshared size_t m_width;
    private static __gshared size_t m_height;
    private static __gshared size_t m_x;
    private static __gshared size_t m_y;

    public static void initialize()
    {
        m_width = fb.width / kfont.advance;
        m_height = fb.height / kfont.line_height;
    }

    public static void clear()
    {
        fb.clear();
        m_x = 0u;
        m_y = 0u;
    }

    public static void write(char ch)
    {
        if (ch == '\n')
        {
            m_x = 0u;
            m_y++;
        }
        else
        {
            render_char(m_x, m_y, ch);
            m_x++;
            if (m_x == m_width)
            {
                m_x = 0u;
                m_y++;
            }
        }
        if (m_y == m_height)
        {
            m_y--;
            fb.copy_rows_up(fb_y(m_height - 1u),
                    (m_height - 1u) * kfont.line_height,
                    kfont.line_height);
        }
    }

    private static void render_char(size_t x, size_t y, char ch)
    {
        const(CharInfo) * ci = &kfont.chars[ch];
        fb.blit_alpha_bitmap(fb_x(x) + ci.left, fb_y(y) + ci.top - ci.height, ci.bitmap, ci.width, ci.height);
    }

    private static size_t fb_x(size_t x)
    {
        return x * kfont.advance;
    }

    private static size_t fb_y(size_t y)
    {
        return fb.height - ((y + 1u) * kfont.line_height);
    }
}