SECTIONS
{
    . = 0xFFFF800000000000;
    _hulk_mem_start = .;
    _hulk_header_start = .;

    .hulk_header :
    {
        KEEP(*(.hulk_header))
    }

    . = ALIGN(4K);
    _hulk_header_end = .;
    _hulk_text_start = .;

    .text :
    {
        *(.text)
        *(.text.*)
    }

    . = ALIGN(4K);
    _hulk_text_end = .;
    _hulk_rodata_start = .;

    .rodata :
    {
        *(.rodata)
        *(.rodata.*)
    }

    . = ALIGN(4K);

    _hulk_rodata_end = .;
    _hulk_data_start = .;

    .data :
    {
        *(.data)
        *(.data.*)
    }

    . = ALIGN(4K);
    _hulk_data_end = .;
    _hulk_binary_size = . - _hulk_mem_start;
    _hulk_bss_start = .;

    .bss :
    {
        *(COMMON)
        *(.bss)
        *(.bss.*)
    }

    . = ALIGN(4K);
    _hulk_bss_end = .;
    _hulk_mem_end = .;

    _hulk_header_size = _hulk_header_end - _hulk_header_start;
    _hulk_text_size = _hulk_text_end - _hulk_text_start;
    _hulk_rodata_size = _hulk_rodata_end - _hulk_rodata_start;
    _hulk_data_size = _hulk_data_end - _hulk_data_start;
    _hulk_bss_size = _hulk_bss_end - _hulk_bss_start;
    _hulk_mem_size = _hulk_mem_end - _hulk_mem_start;
}